Wanted: Migrating To a Newer Image Part 2

In the last post we migrated the Wanted source code to a newer image by using a local Monticello repository. That gave us a working Wanted application, but the WantedItems that we created in the old image weren't copied over. This post will focus on copying the data out of the old image and into the new one.

Write Out the Collection of WantedItems
Fire up the old Squeak image, open a workspace and execute the following:

| out |
out := DataStream newFileNamed:
         '/path-to-your-directory-here/wanted-items.dat'.
out nextPutAll: WantedDatabase wantedItems.
out close

This creates the temp variable out to hold a DataStream object pointing to a new "wanted-items.dat" file. The nextPutAll method takes a collection of objects and writes it to the receiving stream before closing it.

Exit the old Squeak image--this will be the last time we need it. From now on, all things in these tutorials will be done in the new image.

Read In the Collection of WantedItems
Fire up the shiny new image, open a new workspace, and execute the following:

|in|
in := DataStream fileNamed:
        '/path-to-your-directory-here/wanted-items.dat'.
[in atEnd] whileFalse:  
             [WantedDatabase wantedItems add: in next].
in close

The above creates a new DataStream off of the "wanted-items.dat" file (notice we're using the fileNamed message to create the DataStream instead of newFileNamed). The [in atEnd] block will return false until all objects have been read from the file. We pass that block another block that adds each object read in (using the next message) to the WantedDatabase wantedItems collection. Then we close the DataStream.

We now have our old WantedItems in the new image. Open up a browser and head to http://localhost:8080/seaside/wanted. You should see something like this:



Enable File Serving in Commanche
Our new image is not serving our css since Commanche is not enabled to serve files. Paste the following into a new workspace and "do it":

| ma seaside |
HttpService allInstancesDo: 
   [:each | each stop. each unregister].
WAKom  stop.
seaside := WAKom  default.
ma := ModuleAssembly core.
ma serverRoot: FileDirectory default fullName.
ma alias: '/seaside' to: 
   [ma addPlug: [:request | seaside process: request]].
ma documentRoot: FileDirectory default fullName.
ma directoryIndex: 'index.html index.htm'.
ma serveFiles.
(HttpService startOn: 8080 named: 'httpd') plug: ma rootModule

That should get you to this:


That Entered Date Format Has Been Bugging Me
Me too. We can solve that by adding a formatBlock to the WAReportColumn that handles the enteredDate in WantedList>>initialize:

add: 
  ((WAReportColumn selector: #enteredDate title: 'Entered Date')
      formatBlock: 
         [:enteredDate | enteredDate asDate mmddyyyy]; 
      yourself);

We get the date to show up in mm/dd/yyyy format by sending the asDate message to the enteredDate of the WantedItem, then sending the mmddyyyy message to that date.

While we're there, let's modify the "Can Buy" WAReportColumn to show 'Yes' or 'No' instead of the robot-like 'true' or 'false':

add: 
   (WAReportColumn
       renderBlock: 
         [:item | item isPurchasable 
                          ifTrue: ['Yes'] ifFalse: ['No']]
       title: 'Can Buy');

This is accomplished by sending the isPurchasable predicate the ifTrue:ifFalse: message with a "Yes" or "No" value respectively.

Those changes should give you something like this:


Saving Changes
Since we made source changes, we should commit them to our local Monticello repository. Open a Monticello Browser and select the Wanted-Item package in the left pane, and the local repository in the right pane:

Notice that an asterisk appears before the package name: this signifies that changes have occured in the package. Click the Save button and enter a version message describing the changes we made:


When you hit Accept, a version info window will display letting you know that the changes were successfully saved. At this point, save the image so that the WantedItems will be persisted. And that's it for this post--we are now fully migrated over to the new image. By now it feels like we've kinda worn out the simplicity of saving the WantedItems in a collection in the image. If we had had the data in a store somewhere, we could have just pointed the new image there instead of this file reading/writing stuff. Future posts will address this.